Win10 TH2 秋季正式版激活完整教程：KMS 腳本一鍵激活所有版本

微軟發布 Win10 首個重大更新 TH2，系統穩定性與速度大幅提升 (響應速度較 Win7 提升 30%)。但升級後原激活狀態常失效，系統變回未激活。本文提供通用 KMS 激活腳本，自動識別版本導入對應 GVLK 金鑰並連接 KMS 伺服器激活，支援所有 Win10 版本。

激活前準備

1. 開啟任意資料夾 →「檢視」頁籤 → 勾選「文件擴展名」
2. 桌面右鍵 → 新建 → 文字文件

KMS 激活腳本完整內容 (複製至文字文件)

@echo off & setlocal EnableDelayedExpansion & color 3e
title KMS_Activation for Windows 10 - (hnfeng)

echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo :: 自動檢測 Win10 版本，導入對應 KMS 金鑰 ::
echo :: 然後連接指定 KMS 伺服器激活 Win10    ::
echo :: 2015-7, hnfeng                             ::
echo ::::::::::::::::::::::::::::::::::::::::::::::::
echo. & echo.

set KMS_Sev=kms.landiannews.com
call :verchk
call :adminchk

set Core=TX9XD-98N7V-6WMQ6-BX7FG-H8Q99
set CoreCountrySpecific=PVMJN-6DFY6-9CCP6-7BKTT-D3WVR
set CoreN=3KHY7-WNT83-DGQKR-F7HPR-844BM
set CoreSingleLanguage=7HNRX-D7KGG-3K4RQ-4WPJ4-YTDFH
set Professional=W269N-WFGWX-YVC9B-4J6C9-T83GX
set ProfessionalN=MH37W-N47XK-V7XM9-C7227-GCQG9
set Enterprise=NPPR9-FWDCX-D2C8J-H872K-2YT43
set EnterpriseN=DPH2V-TTNVB-4X9Q3-TJR4H-KHJW4
set Education=NW6C2-QMPVW-D7KKK-3GKT6-VCFB2
set EducationN=2WH4N-8QGBV-H22JP-CT43Q-MDWWJ
set EnterpriseS=WNMTR-4C88C-JK8YV-HQ7T2-76DF9
set EnterpriseSN=2F77B-TNFGY-69QQF-B8YKP-D69TJ

for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set EditionID=%%i

if defined %EditionID% (
    cscript //Nologo %windir%\system32\slmgr.vbs /ipk !%EditionID%!
    cscript //Nologo %windir%\system32\slmgr.vbs /skms %KMS_Sev%
    cscript //Nologo %windir%\system32\slmgr.vbs /ato
) else (
    echo. & echo Not found DEFINED Key: "%EditionID%". & echo.
)
pause
exit

:verchk
ver | find "10.0." >nul 2>nul && (goto :EOF)
echo. & echo The current OS is NOT Windows 10. & echo. & pause & exit

:adminchk
reg query "HKU\S-1-5-19" >nul 2>nul || (
    cls & echo. & echo Run as ADMINISTRATOR, Pls. & echo. & echo Press any key to exit. & echo. & pause>nul & exit
)
goto :EOF

執行步驟

1. 將上述代碼貼入文字文件
2. 存檔後將擴展名從 .txt 改為 .bat (彈出提示點「是」)
3. 右鍵 .bat 文件 →「以管理員身份執行」 (關鍵步驟！)
4. 等待腳本自動檢測版本、導入金鑰、連接 KMS、激活完成
5. 出現「成功激活」提示即大功告成

支援版本對照表 (GVLK 金鑰)

注意事項

• KMS 激活有效期 180 天，系統會自動嘗試續約
• 需保持網路連通以連接 KMS 伺服器
• 企業環境建議部署內網 KMS 主機 (slmgr /skms 您的KMS主機IP)
• 此方法僅供測試學習，商業生產環境請購買正版授權

延伸閱讀

• 新手教程：Win10 TH2 正式版 ISO 鏡像安裝方法大全
• 升級 10586 後螢幕閃爍不停解決方案
• Win10 TH2 升級錯誤 0xC1900101 臨時對策
• Win10 TH2 官方 ESD 映像轉 ISO 教程
• 雙系統安裝 Win10 TH2 圖文教程
• Win10 TH2 正式版 10586 鏡像下載官方大全